Community
 
Aggiungi lista preferiti Aggiungi lista nera Invia ad un amico
------------------
Crea
Profilo
Blog
Video
Sito
Foto
Amici
   
 
 

Spice Models for Vacuum Tubes (A Survey) 

    Computer-aided design tools based on Spice Core, as Microsim PSpice, are used almost universally in the design of solid state circuits. Many Designers and  Researchers are conviced that Spice Tools can be a "tremendous boon" for Vacuum-Tube projects. Obviously device models must be accurate and readily available. In this text I check the State of the Art about Vacuum Tubes Models available on WEB and Technical Papers. Models about Diode, Triode, Pentode with their mathematical origin are presented.

 

Diode

    The physical grounds of Vacuum-Diode Models are almost universally based on the Child-Langmuir Law:

(1) Ip= K*Vpk^(1.5);

where: Ip is the current that flows in the diode; Vpk is the anode-to-cathode voltage and K is a costant (perveance). A simple PSpice code, based on the Analog Behavioral Modeling (ABM) program's feature is the following:

.subckt name_diode p k

+ params: k= .....

gp p k value = {K/2*(pwr(v(p,k),1.5)+pwrs(v(p,k),1.5))}

*rpk p k 1meg

.ends name_diode

Unfortunately the current of a diode is influenced from other factors like:

a) The distribution of the potential along the filament (for direct heating diodes);

b) The contact potential;

c) Gas and impurity present inside the bulb;

d) The initial speed of the electrons.

These factors introduce further limits to correctness of the (1) for theoretical (the point d) for instance) and engineering (the point c) for instance) reasons.

A French Researcher [1] have suggested a better model for the vacuum diode adding in (1) the Contact Potential (Vc):

(2) Ip= K*(Vp+Vc)^(1.5)

Using eq. (1) and (2) to apply Levemberg-Marquandt Algorithm (LMA) to experimental data from data sheet we obtains a better Correlation Coefficient R associated with eq.2. A simple PSpice ABM is the following:

.subckt name_diode p k

+ params: k= ..... vc=.....

e1 1 0 value = {v(p,k)+vc}

re1 1 0 1

gp p k value = {K/2*(pwr(v(1),1.5)+pwrs(v(1),1.5))}

*rpk p k 1meg

.ends name_diode

Recently [2], I have proposed a model based on the followin expression:

(3) Ip= (Ka+Kb*Vp)*(Vp+e)^A;

A linear variation to the perveance has been attributed with respect to Vp; further the exponent becomes a parameter. e is a costant that emproves the LMA's convergence. This modifications produce always Correlations Coefficient greater than .9997 and an excellent compliance with measurement results in real world.

A simple Pspice ABM follows:

.subckt diode_name p k

+ Params: Ka=... Kb=.... A=... e=...

e1 1 0 value = {Ka+Kb*v(p,k)}

re1 1 0 1

e2 2 0 value = {v(p,k) + e}

re2 2 0 1

gp p k value = {v(1)/2*(pwr(v(2),A)+pwrs(v(2),a))}

rpk p k 1meg

.ends diode_name

 

TRIODE

Scott Reynolds [3] and W. Marshall Leach, Jr [4], have proposed a simple triode model based on the classic equation:

(4) Ip= K*(m*Vgk+Vpk)^(1.5)

where: K is the perveance; m is the amplifier factor; Vgk is the grid-to-cathode potential; Vpk is the plate-to-cathode potential. Eq. 4 is derived from eq. 1 by replacing Vpk with the Cumulative Potential m*Vgk+Vpk.

Eq. 4 can properly fit triode characteristics only in low Vpk-low |Vgk| area. When Vgk becomes more and more negative eq. 4 is unsatisfactory. Below is the Pspice ABM:

.subckt triode_name p g k

+params: K=... m=... Rgk=... Cgk=... Cgp=... Cpk=...

e1 2 0 value = {v(p,k) +m*v(g,k)}

r1 2 0 1

gp p k value = {K*(pwr(v(2),1.5)+pwrs(v(2),1.5))/2}

******************************

* next code simulates grid current

******************************

rgk g 1 {Rgk}

d1 1 k dm

*****************************

*end code

*****************************

cgk g k {Cgk}

cgp g p {Cgp}

cpk p k {Cpk}

.model dm d

.ends triode_name


In the last years intellectual energies have spend in order to exceed the limitations of the simple model in eq. 4.

Rydel's Approach [1]

Eq. 4 leaves out parasitic phenomenae existing in triode as the depencence of transconductance gm and internal resistance rp (and therefore m) by Vg, when this potential becomes more an more negative. By allowing to change the perveance K with respect to Vg we can mimic the behaviour of triode caracteristics for Vg<<0.

(5) Ip= K*(1+Vgk/B)*(Vg+(Vpk+Vc)/m)^(1.5)

For a better behaviour of positive grid voltage, we can add a further expression in eq. 5

(6) Ip=K*(1+Vgk/B)*((Vgk+(Vpk+Vc)/m)^(1.5))*(Vpk/(Vpk+c))

Where K,B,Vc,c are parameters for a Non Linear Regression Method as, the above mentioned, LMA. Eq. 6 produces an excellent fitting with the published data. The Resercher also suggests a variant for very-non linear triodes:

(7) Ip=K*(1+Vg/(B-Vg/C))*(Vg+(Vp+Vc)/m)^1.5

An often negleted characteristic of triode behaviour is its capacity to draw grid curren when Vg becomes positive (actually tubes draws current also when Vg is weakly negative). Grid current is not easily determinable because it depends on theoretical grounds and engineering proceedings. The suggested expression for grid current is the following:

(8) Ig=G*(((A+Vpk)/(B+Vpk))^4)*Vgk^1.5

Eq. 8 fits well enough real curves but again a Non Linear Regression Method is necessary to speed-up the model drawing

A Pspice ABM for eq (7) can be easily extracted with the pattern about eq.4's ABM.

Koren's Approach [5]

Koren's models are based on the couple of the following expressions:

(9) E1=(Vpk/Kp)*Log(1+exp(Kp((1/m)+Vgk/(sqrt(Kvb+Vpk^2)))

(10) Ip=((E1^Ex)/Kg1)*(1+sgn(E1))

Sign function prevents current flow when E1<0.

This model is well adapted to a manual calibration of parameter.

Ex and Kg1can be adjusted so that curves for weakly negative grid voltages match experimental data; Kp parameter models the behaviour in large negative grid voltage area and Kvb is correlated with the "knee" of plate curves.

Recently [6], I have proposed a little variant on this model adding a polynomial dependence of Ex parameter with respect to plate voltage. This approach is effective for triode with unusual behaviour (as Nuvistors) or for low voltage-low current area (i.e. for a local modeling). I suggest a polynomial Curve Fitting along the plate caracteristic quadrant. A PSpice ABM with standard approach (6sn7 model) and Ex-parameter polynomial fitting (6cw4 model) follow:


.subckt 6sn7 1 2 3 ; plate grid cathode
+ params: mu=21 ex=1.36 kg1=1460 kp=150 kvb=400 rgi=300

+ ccg=2.4p cgp=4p ccp=.7p
e1 7 0 value=
+{v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1g
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends
******************
.subckt 6cw4 1 2 3 ; plate grid cathode NUVISTOR R.C.A.
+ params: mu=68.75 ex=1.35 kg1=160 kp=250 kvb=300 rgi=200
+ ccg=4.1p cgp=.92p ccp=.18p
+ a=2.133e-7 b=-9.40e-5 c=.0139666 d=.64
e1 7 0 value=
+{v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1g
e2 8 0 value=
+{a*v(1,3)*v(1,3)*v(1,3)+b*v(1,3)*v(1,3)+c*v(1,3)+d}
re2 8 0 1g
g1 1 3 value= {(pwr(v(7),v(8))+pwrs(v(7),v(8)))/kg1}
rcp 1 3 1g
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends 6cw4  

Maillet's Approach [7]

A multivariate polynomial curve fitting has been proposed:

(11) Ip=S(i=0..m) S(i=0..n) (aij *Vg^i) * Vp^j

where aij are the coefficients of a Polynomial Curve Fitting derived from another Polynomial Curve Fitting on Data Tables:

[Ip, Vp] @ Vg= cost

extracted from Data-Sheet.

Next Eq. 11 is translated in Pspice ABM with Poly Functions.

A software support as Matlab or Matcad is necessary for this analytical approach.

 

Pentode

Worlwide Hi-Fi interest is on triodes but in Pro_Audio Systems or in High-Power compact Hi-Fi amplifiers four-electrodes devices make the difference.

Reynolds's Approach [3]

The model for tetrode or pentode is based on the following equations:

(12) Ip=Kg1*((Vgk+Vsk/m)^1.5)*(2/p)*arctan(Vpk/10)

(13) Is=Kg2*(Vpk+Vsk/m)^(1.5);

where: Vsk is the screen-to-cathode voltage.

Because Vsk have a greater effect on plate current it replace Vpk in eq.12. The minor influence of plate voltage on plate current is explicated by the arctan term. An example based on this model is shown below.


.
subckt 6l6 1 6 3 4 ; BEAM TETRODE 
g1 2 4 value = {((exp(1.5*(log((v(7,4)/8)+v(3,4)))))/1455)*atan(v(2,4)/10)}
g2 7 4 value = {(exp(1.5*(log((v(7,4)/8)+v(3,4)))))/9270}
c1 3 4 10p
c2 3 1 .6p
c3 1 4 6.5p
r1 3 5 1.5k
r2 2 4 100k
d1 1 2 dx 
d2 4 2  dx2
d3 5 4 dx2
d4 6 7 dx 
d5 4 7 dx2
.model dx d(is=1p rs=1)
.model dx2 d(is=1n rs=1)
.ends 6l6 ; eq. 5881

Leach's Approach [4]

The total instantaneous space current I1 is given by

(14) I1=K*(mcVgk+msVsk+Vpk)^(1.5)

where ms is the screen grid amplification factor and mc is the control grid amplification factor.

The plate current Ip and screen current Is are:

Ip=a*I1

Is=(1-a)*I1

The parameter a is the fraction of space current which flows in the plate.

Rydel's Approach [1]

The model is based on the following expressions:

(15) Ip=Kg1*(Vgk+(Vsk*a/(mg1g2))+Vpk/(m*b)^(1.5)

where:

a=(Vpk-K3*Vgk)/(Vpk+Vsk/K1)

b=1-Vgk/k2

 

K1 coefficient mimic the "rounded" characteristic for low plate voltage; K2 mimic the increase in internal resistance when the command grid becomes more and more negative and K3 permits that characteristics pass through zero when Vg<<0.

The expression for screen grid current is:

(16) Ig2=Kg2*((K1+Vpk)/(K2+Vpk))^(3)*(Vgk+Vsk/K3)^(1.5)

This model is well adapted for a PSpice ABM if curve-fitting methods have priority in coefficients determinations.

Koren's Approach [5]

The proposed equations for pentode model are very similar to triode ones.

(17) E1=(Vsk/Kp)*Log(1+exp(Kp*(1/m+Vgk/Vsk)))

(18) Ip=((E1)^(x)/Kg1)*(1+sgn(E1))*arctan(Vpk/Kvb)

Observe that an arctan factor as in Reynolds's Approach mimic the dipendence of plate current on plate voltage Vpk.

References

[1] Charles Rydel, "Simulation of Electron Tube with SPICE"

AES Pre-Print 3887 (G-2). 98th AES Convention, Paris 1995.

[2] Stefano Perugini, "Vacuum Diode Models and PSpice Simulations"

Glass Audio, Vol. 10, Nr. 4/98.

[3] Scott Reynolds, "Vacuum-Tube Models for Simulations"

Glass Audio, Vol. 5, Nr. 4/93

[4] W. Marshall Leach Jr, "Spice Models for Vacuum Tubes Amplifiers"

JAES, March 1995, p.117

[5] Norman Koren, "Improved Vacuum Tube Models for Spice Simulations"

Glass Audio, Vol. 8, Nr. 5/96

[6] Stefano Perugini, "A low voltage phono preamp with T.H.D. Cancellation"

Glass Audio, Vol. 10, Nr. 2/98.

[7] Jean-Charles Maillet, "Algebraic Technique for Modeling Triodes"

Glass Audio, Vol. 10, Nr. 2/98

What did you think of this article?
Click here to send us your comments, feedback and suggestions