Questo programma è stato scritto per la prima volta in basic compilato, con il DOS 3.30. L'avevo messo nell'autoexec per ricordarmi dei compleanni degli amici. Era, forse, il 1986.

Poi ne ho fatto innumerevoli versioni, anche in VBA per excel e con il Visual Basic 1.

E infine, almeno per ora, in VbScript.

Il programma è semplice, ma proprio per questo mi piace molto. Occupa poco spazio, non deve essere installato, dopo l'uso lascia libera la memoria. In modo semplice avvisa l'utente delle scadenze della prossima settimana.

E' vero che altri programmi fanno la stessa cosa, ma Outlook è una applicazione grossa e pesante. Questo programma invece è lungo 1200 caratteri considerando anche i commenti.

All'inizio viene impostata la variabile miadata alla data corrente e vengono definiti il nome del file contenente l'elenco delle ricorrenze.

Il file (Ricorr.txt, nella stessa directory dello script) viene aperto e ne vengono lette le righe. Il formato delle righe è gg/mm (spazio) Messaggio

Per ciascuna riga si trova la posizione dello spazio che separa la data dal testo.

Quindi si prendono i caratteri prima dello spazio e si trasformano in data.

I caratteri dopo lo spazio rappresentano invece il messaggio da mostrare sullo schermo.

Se la data letta nella riga è compresa tra oggi e oggi+7 (tra una settimana) allora accodo la data e il messaggio alla stringa da mostrare sullo schermo. Per mantenerla separata ci aggiungo un ritorno a capo (VbCrLf). Se volete allungare o accorciare il preavviso delle ricorrenze, basta modificare "oggi+...). Con oggi+1 avrete le scadenze di oggi e domani. Con oggi+10 le scadenze della prossima decade.

A questo punto passo alla prossima riga e ripeto fino alla fine del file.

Se la stringa che dovrebbe contenere i messaggi risulta vuota mostro un messaggio che segnala l'assenza di ricorrenze; se invece contiene qualcosa la faccio apparire in una finestra messaggio.

Scarica da qui il file zip contenente lo script e un piccolo esempio di txt con le ricorrenze.

Giovanni Cenati.

'************************************************
' File:    Ricorrenze.vbs
' Autore:  Giovanni Cenati Reventlov at katamail com
' http://digilander.libero.it/Cenati
' Codice VbScript liberamente utilizzabile citando il sito
' Ricava le ricorrenze che cadono nella prossima
' settimana. By Cenati Giovanni 6.1.98 - VB Script 12.12.01
'************************************************
Oggi = Date 
file= "Ricorr.txt"
title = "Ricorrenze - Cenati"
Mess= "" 'Messaggio da visualizzare
set fso= createobject("Scripting.FileSystemObject")
If fso.FileExists(file) Then
    Set txtStream = fso.OpenTextFile(file) ' Apre file di testo.
    Do While Not (txtStream.atEndOfStream)
        Text = txtStream.ReadLine 'legge una riga
        Separa = inStr(1,Text," ")  'Trova il primo spazio
        miadata= cdate(left(Text,Separa-1)) 'Prima dello spazio c'è la data
        Ricorr= right(Text, len(Text)-Separa) 'Dopo lo spazio c'è la ricorrenza
        If miadata => Oggi And miadata <(Oggi + 7) Then Mess = Mess & Miadata & " " & Ricorr & vbcrlf
		'qui sopra ho aggiunto al messaggio la ricorrenza trovata.        
    Loop
Else                  ' Termina.
    MsgBox "File '" & file & "' non trovato", vbOKOnly + vbCritical, Title 
    WScript.Quit 1    ' Termina con error code 1.
End If
If Mess= "" Then 
     MsgBox "Nessuna ricorrenza nella prossima settimana", 0, title          
Else 
     MsgBox Mess, 0, title
End If 
'*** End